Multiplying Signals

Boot the server to get started.

s.boot;

Ring Modulation

What happens when we multiply two sine waves together? Mathematically we can describe such a signal as follows:

$$A_c\sin(2\pi f_c t) * A_m\sin(2 \pi f_m t)$$

Optionally, we could have added phases for each of our sinusoids as well.

The above is an example of ring mdoluation. Ring modulation is the multiplication of any two signal: one called the modulator and one called the carrier. Note that they need not be sine waves. We can think about the modulating signal as changing the amplitude of the carrier signal. What happens to the frequency content of the output of the multiplied sine waves?

SynthDef(\ringMod, {
  arg out = 0, freq_c = 440, freq_m = 0.25, a_m = 1, a_c = 1;
  Out.ar(out, a_c * SinOsc.ar(freq_c)* a_m * SinOsc.ar(freq_m) ! 2);
}).add;

FreqScope.new;

~ring = Synth(\ringMod);

~ring.set(\freq_m, 1);

~ring.free;

Amplitude Modulation

Amplitude modulation is a variation on ring modulation. Amplitude modulation preserves the carrier signal while adding the sidebands produced by ring modulation.

$$\frac{1}{2}A_c\sin(2\pi f_c t) * (A_c m \sin(2\pi f_m t) + 1)$$

The generalized formula for amplitude modulation is $C(t) * (M(t) + 1)$ where $M(t)$ is the modulator and $C(t)$ is the carrier.

SynthDef(\ampMod, {
  arg out = 0, freq_c = 440, freq_m = 0.25, a_c = 1, modIndex = 1;
  
  // Using 0.5 below to prevent clipping and restrict amplitude range to -1 to +1
  var sig = 0.5* a_c * SinOsc.ar(freq_c) * (a_c * modIndex * SinOsc.ar(freq_m) + 1);
  Out.ar(out, sig ! 2);
}).add;

FreqScope.new;

~amp = Synth(\ampMod);

~amp.set(\freq_m, 200);

~amp.set(\freq_c, 440);

~amp.set(\modIndex, 1);

~amp.free;